home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib09.dsk / HI-RES PAGE 3 DEMO.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  54 lines
  1. 1  REM  **********************
  2. 2  REM  * HIRES PAGE 3 DEMO  *
  3. 3  REM  *  BY HARRY WHITE    *
  4. 4  REM  * COPYRIGHT (C) 1982 *
  5. 5  REM  * BY MICRO-SPARC INC *
  6. 6  REM  * LINCOLN, MA. 01773 *
  7. 7  REM  **********************
  8. 10  TEXT : HOME : PRINT " APPLESOFT HI-RES PAGE 3  DEMONSTRATION"
  9. 20  FOR N = 0 TO 39: PRINT "*";: NEXT : PRINT 
  10. 30  PRINT  SPC( 7);"WHILE YOU ARE READING THIS"
  11. 35  PRINT 
  12. 40  PRINT  SPC( 4);"1 LINE IS BEING DRAWN ON PAGE 1,"
  13. 45  PRINT 
  14. 50  PRINT  SPC( 11);"2 LINES ON PAGE 2,"
  15. 55  PRINT 
  16. 60  PRINT  SPC( 10);"AND 3 LINES ON PAGE 3"
  17. 65  PRINT 
  18. 70  PRINT  SPC( 3);"OF THE HIGH RESOLUTION DISPLAY AREA."
  19. 80  PRINT : PRINT : FOR N = 1 TO 3000: NEXT 
  20. 90  PRINT "PAGES 2 & 3 WILL THEN BE MOVED TO PAGE"
  21. 95  PRINT "1 FOR VIEWING."
  22. 100  REM  *** CLEAR AND DRAW ON PAGE 1
  23. 110  POKE 230,32
  24. 120  CALL 62450
  25. 130  HCOLOR= 3
  26. 140  HPLOT 140,0 TO 140,90
  27. 200  REM  *** CLEAR AND DRAW ON PAGE 2
  28. 210  POKE 230,64
  29. 220  CALL 62450
  30. 240  HPLOT 30,0 TO 30,190: HPLOT 250,0 TO 250,190
  31. 300  REM  *** CLEAR AND DRAW ON PAGE 3
  32. 310  POKE 230,96
  33. 320  CALL 62450
  34. 340  HPLOT 30,20 TO 250,20: HPLOT 30,30 TO 250,30: HPLOT 30,40 TO 250,40
  35. 400  REM  *** GET MESSAGE TO CONTINUE
  36. 405  VTAB 20
  37. 410  PRINT "PLEASE PRESS A KEY WHEN READY TO VIEW"
  38. 415  PRINT "THE MOVE."
  39. 420  GET A$
  40. 430  POKE  -16297,0: POKE  -16300,0: POKE  -16302,0: POKE  -16304,0
  41. 440  FOR N = 1 TO 5000: NEXT 
  42. 500  REM  *** MOVE PAGE 2 TO PAGE 1
  43. 510 HX$ = "2000<4000.5FFFM D823G"
  44. 520  FOR I = 1 TO  LEN(HX$): POKE 511 +I, ASC( MID$ (HX$,I,1)) +128: NEXT : POKE 72,0
  45. 530  CALL  -144: REM  CAN'T CALL -144 FROM A SUBROUTINE
  46. 560  FOR N = 1 TO 5000: NEXT 
  47. 600  REM  *** MOVE PAGE 3 TO PAGE 1
  48. 610 HX$ = "2000<6000.7FFFM D823G"
  49. 620  FOR I = 1 TO  LEN(HX$): POKE 511 +I, ASC( MID$ (HX$,I,1)) +128: NEXT : POKE 72,0
  50. 630  CALL  -144: REM  CAN'T CALL -144 FROM A SUBROUTINE
  51. 660  FOR N = 1 TO 5000: NEXT 
  52. 700  TEXT : HOME 
  53. 710  VTAB 10: HTAB 15
  54. 720  PRINT "THAT'S IT."